One of the best ways to ensure consistent formatting in a Word document is to use styles. But, you might also need to be able to turn these styles into “direct” formatting.

Work space by NordWood Themes

If you apply a style to text, the text will be formatted as the style specifies (e.g., a first-level heading, a block quotation). This helps keep things consistent and avoid forgetting something like applying italics or bold here or there as you’ve done elsewhere.

If you need to change the formatting, just modify the style, and the formatting for all text with that style will update accordingly. There’s no need to update every place the style occurs individually.

So far so good, but making a single document out of many with different style definitions can be a real headache. And styles may not always transfer completely from one computer to another.

Consequently, SBL Press prescribes,

Do not use your word processor’s style option to mark different elements of the text (body text, headings, subheads). (SBL Handbook of Style, §2.1.3)

Other publishers have similar requirements.

If we’re writing for SBL Press or a publisher with similar requirements, does this mean we can’t use styles? Or, if we do use styles, do we consign ourselves to hours more editing work in order to remove them when we’re preparing to send off a typescript?

Fortunately, no. Word styles can be converted to the direct formatting that SBL Press and others want. Here are 9 steps to do just that.¹

1. Add two macros to Word.

If your document doesn’t have footnotes (e.g., parenthetical citations), you can skip down below and just do steps 4–6.

If your document has footnotes, you’ll want to start by creating two macros in Word. A “macro” is a small program that runs inside an Office application like Word.

Don’t worry. You don’t need to know anything about writing a macro. Assuming you use Office 365, just open Word, and go to View > Macros > Create to get started.²

Scroll to the bottom of any macro list that comes up. Press Enter or click on a blank line after anything else in the window.

Copy and paste there the following:

Sub UnLinkNotes()
Application.ScreenUpdating = False
Dim nRng As Range, fNote As Footnote, nRef As String
With ActiveDocument
  For Each fNote In .Footnotes
    With fNote
      With .Reference.Characters.First
        .InsertAfter "]"
        .Characters.Last.Font.Superscript = True
        .Collapse wdCollapseStart
        .InsertCrossReference wdRefTypeFootnote, wdFootnoteNumberFormatted, fNote.Index
        nRef = .Characters.First.Fields(1).Result
        .Characters.First.Fields(1).Unlink
        .InsertBefore "["
        .Characters.First.Font.Superscript = True
      End With
      .Range.Cut
    End With
    Set nRng = .Range
    With nRng
      .Collapse wdCollapseEnd
      .End = .End - 1
      If .Characters.Last <> Chr(12) Then .InsertAfter vbCr
      .InsertAfter nRef & " "
      With .Paragraphs.Last.Range
        .Style = "Footnote Text"
        .Words.First.Style = "Footnote Reference"
      End With
      .Collapse wdCollapseEnd
      .Paste
      If .Characters.Last = Chr(12) Then .InsertAfter vbCr
    End With
  Next
  For Each fNote In .Footnotes
    fNote.Delete
  Next
End With
Set nRng = Nothing
Application.ScreenUpdating = True
End Sub

After this, press Enter to go to a new line again. Then, copy and paste the following:

Sub ReLinkNotes()
Dim i As Integer, j As Integer, k As Integer, l As Integer, FtRng As Range
Application.ScreenUpdating = False
With ActiveDocument
  Set FtRng = Selection.Range
  With FtRng
    .Style = "Footnote Text"
    With .Find
      .ClearFormatting
      .Replacement.ClearFormatting
      .Text = "\[([0-9]{1,})\]"
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindStop
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchAllWordForms = False
      .MatchSoundsLike = False
      .MatchWildcards = True
      .Execute Replace:=wdReplaceAll
    End With
    k = .Paragraphs(1).Range.Words(1) - 1
    j = k
    l = ActiveDocument.Footnotes.Count - k
    For i = 1 To .Paragraphs.Count
      If .Paragraphs(i).Range.Words(1) = j + 1 Then
        j = j + 1
      End If
    Next i
  End With
  For i = k + 1 To j
    StatusBar = "Finding Footnote Location: " & i + l
    With .Content.Find
      .Text = "[" & i & "]"
      .Font.Superscript = True
      .MatchWholeWord = True
      .MatchWildcards = False
      .Execute
      If .Found = True Then
        .Parent.Select
        With Selection
          .Delete
          .Footnotes.Add Range:=Selection.Range, Text:=""
        End With
      End If
    End With
  Next i
  With FtRng
    For i = k + 1 To j
      StatusBar = "Transferring Footnote: " & i + l
      With .Paragraphs(1).Range
        .Cut
        With ActiveDocument.Footnotes(i + l).Range
          .Paste
          .Words(1).Delete
          .Characters.Last.Delete
        End With
      End With
    Next i
  On Error Resume Next
  End With
  Set FtRng = Nothing
End With
Application.ScreenUpdating = True
End Sub

Click the save button, and you can close the Microsoft Visual Basic for Applications window.

Congratulations! You just added two macros to Word. One is tilted UnLinkNotes. The other is titled ReLinkNotes.

You only have to do this step once.³ Now when you go to View > Macros, you should see both UnLinkNotes and ReLinkNotes in the macro list.⁴

2. Save a backup copy of your file.

Just in case something goes wrong, make a backup copy of your document before you run the first macro. That way, you don’t risk losing anything in the unlikely event that something goes awry.

3. Unlink your footnotes.

In order to move Word styles to direct formatting, you’ll need to open the file in WordPad. Unfortunately, WordPad doesn’t support footnotes. So, in order not to lose your footnotes, you need to “unlink” them so that they’re saved as body text that appears in the main page area at the end of your document.⁵

To do this, open your document, and go to View > Macros. Click the UnLinkNotes macro, and click Run.

Be patient. Depending on how long your document is, how many footnotes you have, and how fast your computer is, unlinking the notes may take some time.

When the screen refreshes and you see “^[1]” where the anchor was for your first footnote, the macro should be done.

4. Save your file in RTF.

If it isn’t already, save your file in RTF (“Rich Text Format”). RTF is much like the default DOC(X) format for Word but more basic.

You can do this in Word for Office 365 by going to the File tab > Save a Copy.⁶ Input your desired file name, and choose where you want to save the file.

From the file type dropdown box, choose to save the file in “Rich Text Format (*.rtf).” Then, click Save.

5. Open and resave your RTF file in WordPad.

Open your RTF file in WordPad, or a similar program. Make some minor change to the file (e.g., adding a space somewhere). Save the file. Delete your change, and save the file again.

This process will get WordPad to overwrite the existing RTF file with all Word’s styles in it. When WordPad overwrites the file, it will change all the formatting to “direct” formatting and reset the style for the whole document to “Normal.”

So, for instance, you won’t have a “Heading 1” style in use any more. But, the formatting for the Heading 1 style will still show up where you had applied that style.

Once you’ve completed this step, you can close WordPad.

6. Open your RTF in Word, and resave it in whatever format you need.

If you need to submit the file in DOC or DOCX format, go ahead and resave it in that format now. To do so, open it in Word, and use the same process as in step 4 above.

When you choose the file format, just choose whatever format besides RTF that you actually need.

7. Check for a stray period, and edit accordingly.

When you ran the UnLinkNotes macro, the final punctuation mark (probably a period) in your conclusion may have gotten moved to after your last footnote. If so, you may see no punctuation at the end of your conclusion and two at the end of your last footnote.

If this has happened, add a period after your conclusion, and delete one of the two after your last footnote.

8. Select your footnotes.

Scroll to the end of the document, and find the “¹” that indicates the start of the text of your first footnote.

Use the mouse or keyboard to select the “¹” and all the following text in all of your footnotes. That is, at the end of this step, you should have all your footnotes selected at the same time.

9. Relink your footnotes.

Relink your footnotes by going to View > Macros. Click the ReLinkNotes macro, and click Run.

Be patient. Depending on how long your document is, how many footnotes you have, and how fast your computer is, relinking the notes may take some time.

10. Add any needed paragraph formatting to your footnotes.

After the ReLinkNotes macro finishes, your footnotes will all be back in their places and all flush with the left-hand margin.

If you need to add a first-line indentation, add spacing between footnotes, or adjust the line spacing within the notes, you can do that now by selecting all your footnotes and applying the appropriate formatting.

Conclusion

After these steps, you’ll have a document with the only “Normal” style and direct formatting in use throughout. If you need to shift styles to direct formatting in another document, just repeat steps 2–10 above for that document.

By doing so, you’ll get the benefit of formatting consistency by using styles and save yourself a good amount of work if you need to remove those styles as you prepare to submit your typescript. Happy editing!

What suggestions do you have to get the most out of Word styles and still submit a typescript acceptable to a publisher with a requirement like SBL Press has?